chore: initialized project

modules/flake-module.nix

@@ -0,0 +1,13 @@
+{ lib, ... }:
+{
+  flake.nixosModules =
+    let
+      allModules = import ./top-level.nix;
+    in
+    lib.listToAttrs (
+      map (module: {
+        name = lib.removeSuffix ".nix" (baseNameOf module);
+        value = import module;
+      }) allModules
+    );
+}

modules/services/resonite-server.nix

@@ -0,0 +1,76 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}:
+let
+  cfg = config.services.resonite-server;
+
+  settingsFormat = pkgs.formats.json { };
+  settingsFile = settingsFormat.generate "config.json" cfg.settings;
+in
+{
+  options.services.resonite-server = {
+    enable = lib.mkEnableOption "Resonite headless server";
+
+    settings = lib.mkOption {
+      type = settingsFormat.type;
+      default = { };
+      example = { };
+      description = ''
+        The configuration to run on startup.
+        Read <https://wiki.resonite.com/Headless_server_software/Configuration_file> for details.
+      '';
+    };
+
+    environment = lib.mkOption {
+      type = lib.types.attrsOf lib.types.str;
+      default = { };
+      example = {
+        STEAM_BRANCH = "headless";
+        TZ = "Etc/UTC";
+      };
+      description = ''
+        Environment variables passed to the Resonite container.
+        Check <https://github.com/voxelbonecloud/resonite-headless-docker> for more information.
+      '';
+    };
+
+    environmentFiles = lib.mkOption {
+      type = lib.types.listOf lib.types.path;
+      default = [ ];
+      example = [
+        "/run/secrets/resonite-credentials"
+      ];
+      description = "Environment files for the Resonite container.";
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    services.resonite-server.environment = {
+      STEAM_BRANCH = "headless";
+      CONFIG_FILE = "config.json";
+      TZ = "Etc/UTC";
+    };
+
+    virtualisation.oci-containers = {
+      backend = lib.mkDefault "podman";
+
+      containers.resonite-server = {
+        image = "ghcr.io/voxelbonecloud/resonite-headless-docker:main";
+        pull = "newer";
+
+        inherit (cfg) environment environmentFiles;
+
+        user = "0";
+
+        volumes = [
+          "${settingsFile}:/Config/config.json:ro"
+          "resonite-server-logs:/Logs"
+          "resonite-server-mods:/RML"
+        ];
+      };
+    };
+  };
+}

modules/top-level.nix

@@ -0,0 +1,3 @@
+[
+  ./services/resonite-server.nix
+]